在lostfocus里处理完事务后发个异步消息，在消息处理过程执行text1.setfocus应该可以

好的，那我试试。。

valid事件里根据鼠标点击的位置判断
IF MROW(thisform.Name,3)#-1 and Mcol(thisform.Name,3)#-1
    RETURN 0
endif
但是表单重新激活时,如果直接点其他可以获得焦点的控件,text就可能失去焦点.

DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG
#DEFINE MY_MSG  0x401
of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 as Form
    ADD OBJECT text1 as textbox WITH left=10,top=10,SelectOnEntry=1
    ADD OBJECT text2 as textbox WITH left=10,top=40
    PROCEDURE init
        BINDEVENT(this.hWnd, MY_MSG, this, "myMsg")
    ENDPROC
    PROCEDURE myMsg(hWnd, uMsg, wParam, lParam)
        this.text1.setfocus
    ENDPROC
    PROCEDURE text1.lostfocus
        thisform.text2.value = thisform.text1.value
        PostMessage(thisform.hWnd, MY_MSG, 0, 0)
    ENDPROC
ENDDEFINE

呃，大佬，我再问个题外的问题，我用modi form做的表单，有没有办法把它变成像您这样的PRG程序？

类浏览器中转换

[此贴子已经被作者于2020-7-25 18:32编辑过]

我去试试

静态设计form一样
在表单设计器自定义方法myMsg（菜单--表单--新建方法程序）

OK！ 谢过大侠！！

* 改为下面，将有其他问题
* 测试时，先不要在Text1输入数据，在Text2或者Text3中输入数据，然后再回来Text1输入数据
* 我的测试结果，Text2,Text3会看不见了.
DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG
#DEFINE MY_MSG  0x401
of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 as Form
    ADD OBJECT text1 as textbox WITH left=10,top=10,SelectOnEntry=1
    ADD OBJECT text2 as textbox WITH left=10,top=40
    ADD OBJECT text2 as textbox WITH left=10,top=70 &&增加1个
    PROCEDURE init
        BINDEVENT(this.hWnd, MY_MSG, this, "myMsg")
    ENDPROC
    PROCEDURE myMsg(hWnd, uMsg, wParam, lParam)
        this.text1.setfocus
    ENDPROC
    PROCEDURE text1.lostfocus
*       thisform.text2.value = thisform.text1.value
        PostMessage(thisform.hWnd, MY_MSG, 0, 0)
    ENDPROC
ENDDEFINE