请问大侠，VFP如何去掉一行字符中的括号及括号中内容？
如：[01次]面包[02次]生菜 替换为 面包生菜
    [01次]80,[02次]92,  替换为 80,92,

[此贴子已经被作者于2021-11-10 17:58编辑过]

c="[01次]80,[02次]92,"
n=OCCURS(",",c)
z=''
FOR i=1 TO n
z=z+STREXTRACT(c,']',[,],i)+","
ENDFOR
?z

========================
c=thisform.edit3.Value
n=OCCURS(",",c)
z=""
FOR i=1 TO n
z=z+STREXTRACT(c,']',[,],i)+","
ENDFOR

thisform.edit2.Value=z
===============================
一是：数据只提取]后面的一位数
二是：二行以上的数据，处理后变成一行。

[此贴子已经被作者于2021-11-10 20:21编辑过]

扫描一次字符串好了，“[”开始舍弃，“]”结束舍弃

扫描的代码如何写？

LOCAL xchr,xsubchr
*xchr = "[44次]13,35,[43次]07,46,[42次]14,33"
xchr = "[01次]面包[02次]生菜"

DO WHILE .T.
    xsubchr = STREXTRACT(xchr,'[',']')
    IF LEN(xsubchr)=0
        EXIT
    ENDIF
    xchr = STRTRAN(xchr,'['+xsubchr+']','')
ENDDO

MESSAGEBOX( xchr)

? fun("[01次]面包[02次]生菜") && 面包生菜
? fun("[01次]80,[02次]92")  && 80,92

FUNCTION fun(s)
    ret = ""
    bg = .T.
    FOR i=1 TO LEN(s)
        ch = SUBSTR(s,i,1)
        IF ch == "["
            bg = .F.
            LOOP
        ELSE
            IF ch == "]"
                bg = .T.
                LOOP
            ENDIF
        ENDIF
        IF bg
            ret = ret + ch
        ENDIF
    ENDFOR 
    RETURN ret
ENDFUNC

? fun("[01次]面包[02次]生菜") && 面包生菜
? fun("[01次]80,[02次]92")  && 80,92
FUNCTION Fun(cc)
    z=''
    n=ALINES(ss,cc,4,"]","[")
    FOR n=1 TO n STEP 2
      z=z+ss(n+1)
    ENDFOR
    RETURN z
ENDFUNC
Vfp这类函数很多,自己灵活使用

[此贴子已经被作者于2021-11-10 21:27编辑过]

s = "[01次]面包,[02次]生菜,[01次]80,[02次]92"
?fun(s) 

FUNCTION fun(s)
    p1 = AT("[",s)
    p2 = AT("]",s)
    DO WHILE p1>0 AND p2>p1
        s = STUFF(s,p1,p2-p1+1,"")
        p1 = AT("[",s)
        p2 = AT("]",s)
    ENDDO
    RETURN s
ENDFUNC

谢谢，辛苦了！