如题，请各位老师指点。谢谢！

------解决方案--------------------------------------------------------
Screen.Picture 没有伸缩属性可设置，只能在 Screen 上加一个 image 控件来显示图片：

_Screen.AddObject('background', 'Image')
_Screen.background.Picture = Getpic() && 或者写你自己的图片文件名
_Screen.background.Visible = .T.
_Screen.background.Stretch = 2 && 不想变形就设为 1
_Screen.background.Move(0,0,_Screen.Width,_Screen.Height)

------解决方案--------------------------------------------------------
1、在表单设置里，把图片先设置成与表单大小。
2、把图片的Anchor属性设置成：15
这样，图片就能自动随表单变化了。

表单INIT事件

THISFORM.ADDOBJECT('IMAGE1','IMAGE')
WITH THISFORM.IMAGE1
     .WIDTH = THISFORM.WIDTH
     .HEIGHT = THISFORM.HEIGHT
     .VISIBLE = .T.
     .STRETCH = 2
     .PICTURE=SYS(5)+SYS(2003)+'\2.JPG'
ENDWITH 

贴图，在init中设置stretch是不够的，那只能在窗体启动时有效，当用户拉伸窗体边框时就失效了。

解压运行试试：

收到的鲜花

• 陶然愚者 于 2013-02-04 08:11 送鲜花  3朵   附言：谢谢！

对头......

非常妙。能提供原代码，讲解下实现方法吗？

Main()
RETURN 

PROCEDURE Main
    LOCAL loForm
    loForm = CREATEOBJECT("_Form")
    WITH loForm
        .Caption = "桌面背景测试程序"
        .Show
    ENDWITH
    READ EVENTS
ENDPROC 

DEFINE CLASS _Form AS Form
    ShowWindow = 2
   
    ADD OBJECT PROTECTED imgBackground AS Image WITH Picture = "Z:\test\VFP\China 06.JPG"
   
    PROCEDURE Activate
        This.Resize
    ENDPROC
   
    PROCEDURE Resize
        WITH ThisForm
            .Width = .Height * .imgBackground.Scale
            .imgBackground.Resize
        ENDWITH
        DODEFAULT()
    ENDPROC
   
    PROCEDURE imgBackground.Init
        WITH This
            .Stretch = 0
            .AddProperty("Scale", .Width / .Height)
            .Stretch = 1
        ENDWITH
    ENDPROC
   
    PROCEDURE imgBackground.Resize
        WITH This
            .Top = 0
            .Left = 0
            .Height = .Parent.Height
            .Width = .Parent.Width
        ENDWITH
    ENDPROC
   
    PROCEDURE Destroy
        CLEAR EVENTS
    ENDPROC
   
ENDDEFINE

谢谢！拷贝下来慢慢学习领会......